W3CHINA.ORG讨论区--[求助] 第一次处理的xml结果作为第二次处理的输入，2步骤的工作，xslt 能不能一次实现?

贴子主题： [求助] 第一次处理的xml结果作为第二次处理的输入，2步骤的工作，xslt 能不能一次实现?

本主题类别: 样式表技术(XSL, XSLT, XSL-FO, CSS)

按照你的思路，答案是肯定的。可以使用一个方法来把两次运行放在一个XSL里边：
注：本Stylesheet使用了XSLT2.0的特性。
XML:
=====================================
<?xml version="1.0" encoding="UTF-8"?>

<mybook>
    <title>XML bible</title>
    <chapter chapnbr="1">
        <title>Introduction</title>
        <para>This is a para</para>
    </chapter>
</mybook>

XSL:
====================================
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" encoding="UTF-8" indent="yes"/>

    <xsl:template match="/">
        <xsl:variable name="v_content">
            <xsl:apply-templates/>
        </xsl:variable>

        <xsl:apply-templates select="$v_content/*"/>
    </xsl:template>

    
    <xsl:template match="chapter">
        <xsl:element name="{concat(name(),'_1')}">
            <xsl:apply-templates select="node()|@*"/>
        </xsl:element>
    </xsl:template>

    
    <xsl:template match="chapter_1">
        <xsl:element name="{concat(name(),'_2')}">
            <xsl:apply-templates select="node()|@*"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{name()}">
            <xsl:apply-templates select="node()|@*"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:attribute name="{name()}">
            <xsl:value-of select="."></xsl:value-of>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

输出:
====================================
<?xml version="1.0" encoding="UTF-8"?>
<mybook>
    <title>XML bible</title>
    <chapter_1_2 chapnbr="1">
        <title>Introduction</title>
        <para>This is a para</para>
    </chapter_1_2>
</mybook>


	W 3 C h i n a ( since 2003 ) 旗下站点苏ICP备05006046号《全国人大常委会关于维护互联网安全的决定》《计算机信息网络国际联网安全保护管理办法》	78.125ms