W3CHINA.ORG讨论区 - 语义网·描述逻辑·本体·RDF·OWL--显示贴子

以文本方式查看主题

-  W3CHINA.ORG讨论区 - 语义网·描述逻辑·本体·RDF·OWL  (http://bbs.xml.org.cn/index.asp)
--  『 XML源码及示例(仅原创和转载) 』  (http://bbs.xml.org.cn/list.asp?boardid=32)
----  将由Ado得到的记录集输出到xml文件  (http://bbs.xml.org.cn/dispbbs.asp?boardid=32&rootid=&id=5371)

--  作者：小鞋子
--  发布时间：2/16/2004 10:40:00 AM

--  将由Ado得到的记录集输出到xml文件

<%
' 删除已经存在的文件
Dim objFSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(Server.MapPath("db_xml.xml")) Then
  objFSO.DeleteFile Server.MapPath("db_xml.xml")
End IF
Set objFSO = Nothing

' 定义变量，很好的习惯
Dim cnnXML ' ADO 连接
Dim rstXML ' ADO 记录集

Set cnnXML = Server.CreateObject("ADODB.Connection")

cnnXML.Open "Provider=SQLOLEDB;Data Source=10.2.1.214;" _
& "Initial Catalog=samples;User Id=samples;Password=password;" _
& "Connect Timeout=15;Network Library=dbmssocn;"

Set rstXML = Server.CreateObject("ADODB.Recordset")
Set rstXML = cnnXML.Execute("SELECT * FROM scratch ORDER BY id;")

Response.Write "<p>Saving data as XML...</p>" & vbCrLf

' 保存xml各式的文件.
rstXML.Save Server.MapPath("db_xml.xml"), adPersistXML

' 关闭数据库连接，释放对象
rstXML.Close
Set rstXML = Nothing
cnnXML.Close
Set cnnXML = Nothing

Response.Write "<p>XML file written...</p>" & vbCrLf
Response.Write "<p>Click <a href=""db_xml.xml"">here</a> to view the file.</p>" & vbCrLf
%>

--  作者：小鞋子
--  发布时间：2/16/2004 11:29:00 AM

--
如果不生成xml文件可以这样.
转载:
http://expert.csdn.net/Expert/topic/2711/2711439.xml?temp=8.472842E-02

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[test]') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
drop table [dbo].[test]
GO

CREATE TABLE [dbo].[test] (
[id] [int] IDENTITY (1, 1) NOT NULL ,
[name] [varchar] (50) COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY]
GO

<%@ LANGUAGE = VBScript %>
<% Option Explicit %>
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Developer Studio"/>
<META HTTP-EQUIV="Content-Type" content="text/html" charset="iso-8859-1"/>
<TITLE>ADO 2.6 E</TITLE>

<%
Response.Write "<H3>Server-side processing</H3>"

Dim adoConn
Set adoConn = Server.CreateObject("ADODB.Connection")

Dim sConn
sConn = "Provider=SQLOLEDB;Data Source=.;Initial Catalog=test;User ID=SA;Password=11;"
adoConn.ConnectionString = sConn
adoConn.Open

Dim adoCmd
Set adoCmd = Server.CreateObject("ADODB.Command")
Set adoCmd.ActiveConnection = adoConn
Dim sQuery
sQuery = "<ROOT xmlns:sql='urn:schemas-microsoft-com:xml-sql'><sql:query>SELECT * FROM test FOR XML AUTO</sql:query></ROOT>"

Dim adoStreamQuery
Set adoStreamQuery = Server.CreateObject("ADODB.Stream")
adoStreamQuery.Open
adoStreamQuery.WriteText sQuery, adWriteChar
adoStreamQuery.Position = 0

Set adoCmd.CommandStream = adoStreamQuery
adoCmd.Dialect = "{5D531CB2-E6Ed-11D2-B252-00C04F681B71}"

Response.write "Pushing XML to client for processing " & "<BR/>"

adoCmd.Properties("Output Stream") = Response
Response.write "<XML ID='MyDataIsle'>"
adoCmd.Execute , , adExecuteStream
Response.write "</XML>"
%>

<SCRIPT language="VBScript" For="window" Event="onload">

   Dim xmlDoc
   Set xmlDoc = MyDataIsle.XMLDocument
   xmlDoc.resolveExternals=false
   xmlDoc.async=false

   Dim root, child
   Set root = xmlDoc.documentElement

   For each child in root.childNodes
      dim OutputXML
      OutputXML = document.all("log").innerHTML
      document.all("log").innerHTML = OutputXML & "<LI>" & child.getAttribute("name") & "</LI>"
   Next

</SCRIPT>
</HEAD>
<BODY>
   <H3>Client-side processing of XML Document MyDataIsle</H3>
   <UL id=log>
   </UL>
</BODY>
</HTML>

W 3 C h i n a ( since 2003 ) 旗下站点
苏ICP备05006046号《全国人大常委会关于维护互联网安全的决定》《计算机信息网络国际联网安全保护管理办法》

2,593.750ms